home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Compute! Gazette 1984 June
/
1984-06.d64
/
file copier
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2022-09-20
|
847b
|
36 lines
10 poke251,peek(52)
20 poke52,peek(44)+4:poke56,peek(52):clr
30 print"[147]run this program to"
40 print"copy a program or"
50 print"sequential file from"
60 print"one disk (the source"
70 print"disk) to another (the"
80 print"destination disk)."
90 print"insert source disk."
100 m=256*peek(52)
110 open15,8,15
120 print"what is the name of"
130 print"the file or program":inputf$
140 t$="p":print"what is the file type"
150 print"(p for program, s for"
160 print"file)"
170 inputt$
180 open2,8,2,f$+","+t$+",r"
190 input#15,e,e$,x,x:ife<>0thenprinte$:close2:goto120
200 get#2,a$:ifa$=""thena$=chr$(0)
210 pokem+j,asc(a$):j=j+1:ifst=0then200
220 close2
230 print"insert destination"
240 print"disk and press return"
250 print"to copy."
260 getc$:ifc$<>chr$(13)then260
270 print"press return[146] if you"
280 print"want to keep the name"
290 printf$
300 input"file name ";f$
310 open2,8,2,f$+","+t$+",w"
320 input#15,e,e$,x,x:ife<>0thenprinte$:close2:goto300
330 fork=0toj-1:print#2,chr$(peek(m+k));:next
340 close2:close15
350 poke52,peek(251):poke56,peek(251):clr